Add other completion path

[Turiok]

Hello,

I'm using zinit but I'm not an expert and I have a problem.
I'm trying to use the autocompletion of poetry CLI.
The plugin is in oh-my-zsh : https://github.com/ohmyzsh/ohmyzsh/tree/master/plugins/poetry
It doesn't contains the completion but the command to create it.
And It create it in path : $ZSH_CACHE_DIR/completions/_poetry
Same problem for kubectl CLI : https://github.com/ohmyzsh/ohmyzsh/tree/master/plugins/kubectl

How to add this completion path for zinit?

I tried and it works to use this command : zinit creinstall $ZSH_CACHE_DIR/completions
But We have to do it only once and in interadtive session. It's written in the README.

But I would like to have dotfile. In case I have to reinstall my OS.

.zshrc

###########################################################{{{
# INIT

# Enable Powerlevel10k instant prompt. Should stay close to the top of ~/.zshrc.
# Initialization code that may require console input (password prompts, [y/n]
# confirmations, etc.) must go above this block, everything else may go below.
if [[ -r "${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh" ]]; then
  source "${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh"
fi

# # Load and initialize the completion system ignoring insecure directories with a
# # cache time of 20 hours, so it should almost always regenerate the first time a
# # shell is opened each day.
autoload -Uz compinit promptinit
_comp_files=(${ZDOTDIR:-$HOME}/.zcompdump(Nm-20))
if (( $#_comp_files )); then
    compinit -i -C
else
    compinit -i
fi
unset _comp_files
###########################################################}}}

###########################################################
# Set options

# Remove older command from the history if a duplicate is to be added.
setopt HIST_IGNORE_ALL_DUPS

# Complete from both ends of a word.
setopt complete_in_word

# Move the cursor to the end of a completed word.
setopt always_to_end

# Perform path search even on command names with slashes.
setopt path_dirs

# Show completion menu on successive tab press.
setopt auto_menu

# Automatically list choice on ambiguous completion.
setopt auto_list

# If completed parameter is a directory, add a trailing slash.
setopt auto_param_slash

# Treat words like bash does, e.g., when we have a path like
# /foo/bar and C-w is pressed, delete only "bar".
autoload -U select-word-style
select-word-style bash

#  History Settings {{{{
HISTFILE="${ZDOTDIR:-$HOME}/.zhistory"
HISTSIZE=10000
SAVEHIST=10000
setopt appendhistory notify
unsetopt beep nomatch
# Treat the '!' character specially during expansion.
setopt bang_hist
# Write to the history file immediately, not when the shell exits.
setopt inc_append_history
# Share history between all sessions.
setopt share_history
# Expire a duplicate event first when trimming history.
setopt hist_expire_dups_first
# Do not record an event that was just recorded again.
setopt hist_ignore_dups
# Delete an old recorded event if a new event is a duplicate.
setopt hist_ignore_all_dups
# Do not display a previously found event.
setopt hist_find_no_dups
# Do not record an event starting with a space.
setopt hist_ignore_space
# Do not write a duplicate event to the history file.
setopt hist_save_no_dups
# Do not execute immediately upon history expansion.
setopt hist_verify
# Show timestamp in history
setopt extended_history
# }}}}

#  Zstyle {{{{
zstyle ':completion:*' menu select
zstyle ':completion:*:matches' group 'yes'
zstyle ':completion:*:options' description 'yes'
zstyle ':completion:*:options' auto-description '%d'
zstyle ':completion:*:corrections' format ' %F{green}-- %d (errors: %e) --%f'
zstyle ':completion:*:descriptions' format ' %F{yellow}-- %d --%f'
zstyle ':completion:*:messages' format ' %F{purple} -- %d --%f'
zstyle ':completion:*:warnings' format ' %F{red}-- no matches found --%f'
zstyle ':completion:*:default' list-prompt '%S%M matches%s'
zstyle ':completion:*' format ' %F{yellow}-- %d --%f'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' verbose yes
zstyle ':completion::complete:*' use-cache on
zstyle ':completion::complete:*' cache-path "$HOME/.zcompcache"
# zstyle ':completion:*' list-colors $LS_COLORS
#zstyle ':completion:*' list-colors dircolors
zstyle ':completion:*:*:kill:*:processes' list-colors '=(#b) #([0-9]#) ([0-9a-z-]#)*=01;34=0=01'
zstyle ':completion:*' matcher-list 'm:{a-zA-Z}={A-Za-z}' 'r:|[._-]=* r:|=*' 'l:|=* r:|=*'
zstyle ':completion:*:functions' ignored-patterns '(_*|pre(cmd|exec))'
zstyle ':completion:*' rehash true
zstyle ':completion:*:sudo:*' command-path /usr/local/sbin /usr/local/bin \
                             /usr/sbin /usr/bin /sbin /bin /usr/X11R6/bin

# Evite les doublons
zstyle ':completion:*:rm:*' ignore-line yes
zstyle ':completion:*:mv:*' ignore-line yes
zstyle ':completion:*:cp:*' ignore-line yes
# }}}}

[ -f ~/.fzf.zsh ] && source ~/.fzf.zsh

if [[ -d /usr/share/fzf ]]; then
    source /usr/share/fzf/key-bindings.zsh
fi

# Do not update oh-my-zsh because the update are with zinit.
DISABLE_UPDATE_PROMPT=true
DISABLE_AUTO_UPDATE=true


# To customize prompt, run `p10k configure` or edit ~/.p10k.zsh.
[[ ! -f "${ZDOTDIR:-$HOME}/.p10k.zsh" ]] || source "${ZDOTDIR:-$HOME}/.p10k.zsh"

# Source custom conf and aliases for RPI shell
[[ ! -f "${ZDOTDIR:-$HOME}/.myEnvDevProfile.sh" ]] || source "${ZDOTDIR:-$HOME}/.myEnvDevProfile.sh"

###########################################################

# ZINIT

###########################################################

[[ ! -f "${ZDOTDIR:-$HOME}/.zinit.zsh" ]] || source "${ZDOTDIR:-$HOME}/.zinit.zsh"

.zinit.zsh

##############################################
# zinit installation
##############################################
if [ ! -d "${HOME}/.zinit" ]; then
    mkdir -p "${HOME}/.zinit" && \
         git clone "https://github.com/zdharma-continuum/zinit" ${HOME}/.zinit/bin
fi

##############################################
# Zinit start up
##############################################
source "${HOME}/.zinit/bin/zinit.zsh"

##############################################
# Zinit configuration 
##############################################

# powerlevel10k - https://github.com/romkatv/powerlevel10k
zinit ice depth'1' # clone only the depth value
zinit light romkatv/powerlevel10k

# zsh-history-substring-search - https://github.com/zsh-users/zsh-history-substring-search
zinit wait lucid atload"bindkey '^[[A' history-substring-search-up;
    bindkey '^[[B' history-substring-search-down" for \
        zsh-users/zsh-history-substring-search

# Moyen d'ajouter les completions avec oh-my-zsh
# oh my zsh plugin - https://github.com/ohmyzsh/ohmyzsh/tree/master/plugins/
zinit wait lucid light-mode for \
    as"completion" \
        OMZ::plugins/docker/_docker \
    as"completion" \
        OMZ::plugins/docker-compose/_docker-compose \
    as"completion" \
        OMZ::plugins/gradle/_gradle \
    as"completion" \
        OMZ::plugins/pip/_pip \
    as"completion" \
        OMZ::plugins/httpie/_httpie \

# Moyen d'ajouter des alias avec oh-my-zsh
# oh my zsh plugin - https://github.com/ohmyzsh/ohmyzsh/tree/master/plugins/
zinit wait lucid for \
    OMZP::sudo \
    OMZP::extract \
    OMZP::archlinux \
    OMZP::common-aliases \
    OMZP::pip \
    OMZP::poetry \
    OMZP::docker-compose \
    OMZP::gradle \
    OMZP::kubectl \
    OMZP::kubectx

# alias-tips - https://github.com/djui/alias-tips
zinit ice wait lucid
zinit light 'djui/alias-tips'

# fast-syntax-highlighting - https://github.com/zdharma-continuum/fast-syntax-highlighting.git
# zsh-syntax-highlighting - https://github.com/zsh-users/zsh-syntax-highlighting
# zsh-completions - https://github.com/zsh-users/zsh-completions
zinit wait lucid for \
 atinit"ZINIT[COMPINIT_OPTS]=-C; zicompinit; zicdreplay" \
    zdharma-continuum/fast-syntax-highlighting \
 blockf \
    zsh-users/zsh-completions \
 atload"!_zsh_autosuggest_start" \
    zsh-users/zsh-autosuggestions

# transcrypt - https://github.com/elasticdog/transcrypt/
zinit ice wait lucid as"program" pick"transcrypt"
zinit light 'elasticdog/transcrypt'

# gita - https://github.com/nosarthur/gita
zinit ice wait lucid as"completion" 
zinit snippet https://github.com/nosarthur/gita/blob/master/.gita-completion.zsh

# LS_COLORS -  https://github.com/trapd00r/LS_COLORS
zinit lucid \
 atclone"[[ -z ${commands[dircolors]} ]] && local P=g
     ${P}dircolors -b LS_COLORS > clrs.zsh" \
 atpull'%atclone' pick"clrs.zsh" nocompile'!' \
 atload'zstyle ":completion:*:default" list-colors "${(s.:.)LS_COLORS}";' for \
    trapd00r/LS_COLORS

[pschmitt]

You're probably looking for:

zinit creinstall -q /path/to/your/comps

[Turiok]

I tried with -q or -Q options but doesn't seems to work.
It does it every zsh session.
It'll be cool to make this command on plugin load but only after at_pull

Output

[WARNING]: Console output during zsh initialization detected. -- console output produced during zsh initialization follows --

==> Installed 2 completions

[pschmitt]

Your issue boils down to the fact that you do not let zinit handle your completions.

https://github.com/zdharma-continuum/zinit#completions-2

[vladdoster]

@Turiok,

You can also do the following:

zi is-snippet param"ZSH_CACHE_DIR->$ZINIT[HOME_DIR]" for @OMZP::poetry